Bill McCarthy在那篇《Modify a Varialbe's Pointer》里用SafeArray实现多进程的数组共享内存，他考虑了数组变量的类型，因此可以兼容大部分数值类型的数组，是一个非常不错的东西。我这里不讲它实现的具体方法，只是想和大家一起看看SafeArray还能做什么。
修改SafeArray结构的pvData指针却是一个非常有用的技术，通过修改pvData，就能够通过数组直接访问指定的内存。
和上一篇文章包装字串指针类一样，通过修改pvData，我们也可以包装一些普通数值类型变量的指针类。
我在指针的第一篇文章里说过，要想实现C语言里'*'这个取指针所指变量值功能，必须要用CopyMemory。实际上，我说错了，我们完全可以实现和C里一样的指针，如下：
//C语言
Long L;
Long* pL = &L;
*pL = 12;
printf("L = %d *pL = %d", l, *pl);
'VB里
Dim pL As New pLong, L As Long
pL.Attach L
'也可以 pL.Ptr = VarPtr(L)
pL = 12
Debug.Print "L ="; L; " *pL ="; pL |
结果都能够通过修改pL指针，达到修改变量L的目的。
上面VB代码里的pLong就是一个包装好的Long型变量的指针类，下面看看如何来实现它：
Option Explicit
'********************************************************
'pLong.cls
'包装一个Long型指针的类
'作者: 熊超 ID: AdamBear 2002年3月18日
'http://www.csdn.net/Author/AdamBear
' 你可以自由使用本类模块，不过请保留本声明
'********************************************************
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)
Private m_Arr(0) As Long
'缺省属性
Public Property Get Data() As Long
Data = m_Arr(0)
End Property
Public Property Let Data(ByVal Value As Long)
m_Arr(0) = Value
End Property
Public Sub Attach(Target As Long)
Ptr = VarPtr(Target)
End Sub
Public Property Let Ptr(ByVal Target As Long)
Dim pSA As Long
'得到SafeArray结构指针pSA
CopyMemory pSA, ByVal VarPtrArray(m_Arr), 4
'这个指针偏移12个字节后就是pvData指针
CopyMemory ByVal (pSA + 12), Target, 4
End Property
Public Property Get Ptr() As Long
Ptr = m_SA.pvData
End Property
Private Sub Class_Terminate()
CopyMemory ByVal VarPtrArray(m_Arr), 0&, 4
End Sub |
要将它改成Byte的指针类，只需要将上面的代码中m_Arr数组的类型，Data属性和Attach方法中的参数类型改为Byte型即可。
当我们这样做出pLong、pByte、pInteger后，我们就能够玩点和C里一样的花样了。
Sub Main()
Dim pB As New pByte, B As Byte
Dim pI As New pInteger, I As Integer
Dim pL As New pLong, L As Long
'用Attach方法将经过类型检查，直接用Ptr属性则可以绕过类型检查
pB.Attach B
pI.Attach I
pL.Attach L
'试试指针
B = 1
Debug.Print "B ="; B; " *pB ="; pB
pB = 1
Debug.Print "B ="; B; " *pB ="; pB
I = 1000
Debug.Print "I ="; I; " *pI ="; pI
pI = 2000
Debug.Print "I ="; I; " *pI ="; pI
L = 40000
Debug.Print "L ="; L; " *pL ="; pL
pL = 60000
Debug.Print "L ="; L; " *pL ="; pL
'试试C里的类型转换
'用Integer指针访问Long型变量
pI.Ptr = VarPtr(L)
Debug.Print "*pI ="; pI
End Sub |
搞出这几种普通数值类型的指针类有什么用？基本上没有什么大用。不过是证明一种方法的可行性，和演示技术。这种技术还有什么用，需要的时候还会再谈。
|
|
